2 files changed, 49 insertions, 0 deletions
diff --git a/racket/aoc2023/day-09/day-09-polynomial.rkt b/racket/aoc2023/day-09/day-09-polynomial.rkt
new file mode 100644
index 0000000..5bacb1f
--- /dev/null
+++ b/racket/aoc2023/day-09/day-09-polynomial.rkt
@@ -0,0 +1,17 @@
+#lang racket
+
+(require advent-of-code
+         threading
+         simple-polynomial/tools)
+
+(define histories
+  (for/list ([raw-history (in-lines (open-aoc-input (find-session) 2023 9 #:cache #true))])
+    (~>> raw-history 
+         string-split 
+         (map string->number))))
+
+(for/lists (left right #:result (cons (apply + left) (apply + right)))
+           ([history (in-list histories)])
+  (define f (interpolate-at-integer-points history))
+  (values (f -1) 
+          (f (length history))))
diff --git a/racket/aoc2023/day-09/day-09.rkt b/racket/aoc2023/day-09/day-09.rkt
new file mode 100644
index 0000000..5eda1eb
--- /dev/null
+++ b/racket/aoc2023/day-09/day-09.rkt
@@ -0,0 +1,32 @@
+#lang racket
+
+(require advent-of-code
+         threading)
+
+(define histories
+  (for/list ([raw-history (in-lines (open-aoc-input (find-session) 2023 9 #:cache #true))])
+    (~>> raw-history 
+         string-split 
+         (map string->number))))
+
+(define (constant? xs) 
+  (= 1 (length (remove-duplicates xs))))
+
+(define/match (derivative xs)
+  [((list a b)) (list (- b a))]
+  [((list* a b _)) (cons (- b a) (derivative (rest xs)))])
+
+(define (extrapolate xs) 
+  (if (constant? xs) 
+      (car xs) 
+      (+ (last xs) (extrapolate (derivative xs)))))
+
+;; part 1
+(~>> histories 
+     (map extrapolate) 
+     (apply +))
+
+;; part 2
+(~>> histories 
+     (map (λ~> reverse extrapolate)) 
+     (apply +))