1 files changed, 56 insertions, 0 deletions
diff --git a/src/gleam/dynamic.gleam b/src/gleam/dynamic.gleam
index b920306..b737c0a 100644
--- a/src/gleam/dynamic.gleam
+++ b/src/gleam/dynamic.gleam
@@ -996,6 +996,62 @@ pub fn decode4(
   }
 }
 
+/// Decode 5 values from a `Dynamic` value.
+///
+/// ## Examples
+///
+/// ```gleam
+/// > from(#(1, 2.1, "3", "4", "5"))
+/// > |> decode5(
+/// >   MyRecord,
+/// >   element(0, int),
+/// >   element(1, float),
+/// >   element(2, string),
+/// >   element(3, string),
+/// >   element(4, string),
+/// > )
+/// Ok(MyRecord(1, 2.1, "3", "4", "5"))
+/// ```
+///
+/// ```gleam
+/// > from(#("", "", "", "", ""))
+/// > |> decode5(
+/// >   MyRecord,
+/// >   element(0, int),
+/// >   element(1, float),
+/// >   element(2, string),
+/// >   element(3, string),
+/// >   element(4, string),
+/// > )
+/// Error([
+///   DecodeError(expected: "Int", found: "String", path: ["0"]),
+///   DecodeError(expected: "Float", found: "String", path: ["1"]),
+/// ])
+/// ```
+///
+pub fn decode5(
+  constructor: fn(t1, t2, t3, t4, t5) -> t,
+  t1: Decoder(t1),
+  t2: Decoder(t2),
+  t3: Decoder(t3),
+  t4: Decoder(t4),
+  t5: Decoder(t5),
+) -> Decoder(t) {
+  fn(x: Dynamic) {
+    case t1(x), t2(x), t3(x), t4(x), t5(x) {
+      Ok(a), Ok(b), Ok(c), Ok(d), Ok(e) -> Ok(constructor(a, b, c, d, e))
+      a, b, c, d, e ->
+        Error(list.flatten([
+          all_errors(a),
+          all_errors(b),
+          all_errors(c),
+          all_errors(d),
+          all_errors(e),
+        ]))
+    }
+  }
+}
+
 fn all_errors(result: Result(a, List(DecodeError))) -> List(DecodeError) {
   case result {
     Ok(_) -> []